Иллюстрированный самоучитель по созданию Flash-игр

Погоня в лабиринте

Сетка помогает быстро создать фон с помощью инструмента рисования прямоугольников. Для этого нужно обвести контуром некоторые области сетки и залить их цветом. Вы должны быть уверены, что границы фона немного перекрывают линии сетки. Когда программа будет помешать ягоды на пересечения линий сетки, они не появятся вдоль границы фона.

Первый кадр клипа "fox" – обычный статический кадр, в остальных кадрах представлена небольшая анимация – лиса съедает ягоду. Когда это происходит, клип воспроизводит второй кадр: игрок видит, как лиса ест ягоду, а затем клип возвращается к первому кадру.

В клипе "berry" два кадра: первый содержит изображение ягоды, а второй пустой. Когда лиса съедает ягоду, клип переходит ко второму кадру. Таким образом, клипы остаются на рабочем поле, но они видны до тех пор, пока ягода не будет съедена.

Клип "bunny" представляет собой анимацию: кролик всегда двигается, так что нет необходимости создавать статический кадр.

Все клипы, кроме "background", не будут видны до тех пор, пока не начнется ролик и программа не создаст их с помощью команды attachMovie.

В ролике содержатся практически такие же кадры, что и в ролике игры "Space Rocks": "start", "play", "lose life", "level over" и "game over".

Создание кода

В первом кадре содержится копия кнопки Play (Начать игру). Сценарий этого кадра не только переводит ролик к кадру "play", но и устанавливает несколько переменных.

on(press) {
    lives = 3;
    score = 0;
    gameLevel = 1;
    gotoAndPlay("play");
}

В кадре "play" содержится клип "actions" с прикрепленным к нему сценарием. Этот сценарий инициализирует все элементы в начале игры, после того как лиса теряет жизнь и перед началом нового уровня. Он также вызывает функции move и moveBunny для продолжения игры.

onClipEvent(load) {
    // Инициализируем исходные элементы 
    _root.startLevel();
}
onClipEvent(enterFrame) {
    // Перемещаем лису.
    _root.move();
    // Перемещаем кролика.
    _root.moveBunny();
}

Все функции этой игры можно найти в сценарии основной временной шкалы для кадра "play". Сначала идет функция startLevel.

Основная работа данной функции заключается в создании ягод, для этого просматриваются все 15 положений по вертикали и 21 положение по горизонтали и проверяется, не расположены ли они поверх клипа "background". Если нет, то на пересечении линий сетки помешаются клипы "berry", а в массив berries добавляются указатели на эти клипы.

Также эта функция создает экземпляры клипов "fox" и "bunny", создает и устанавливает несколько новых свойств для каждого клипа, в том числе и dest (новое положение).

Обратите внимание, что свойство dest для клипов "fox" и "bunny" представляет собой просто координату: (х:275, у.275}. Благодаря этому значительно упрощается обращение к данным величинам. Например, можно обратиться к новому горизонтальному положению клипа, записав fox.deet.x.

function startLevel() {
    level = 0;
    // Создаем ягоды,
    berries = new Array();
    // Ищем пересечения линий сетки,
    for (y = 1; y < 16; y++) {
        for (x = 1; x < 22; x++) {
            // Выясняем, расположены ли пересечения поверх фона.
            if (!(background.hitTest(x * 25, y * 25, true))) {
                // Создаем и размещаем клип "berry".
                attachMovie("berry", "berry" + level, level);
                clip = _root["berry" + level];
                clip._x = x * 25;
                clip._y = y * 25;
                // Добавляем клип в массив berries.
                berries.push(clip);
                level++;
            }
        }
    }
    // Создаем клип с лисой и определяем его положение.
    attachMovie("fox", "fox", level++);
    fox._x = 275;
    fox._y = 275;
    // Определяем направление движения и координаты цели,
    fox.move = {
        x: 0;
        y: 0
    };
    fox.dest = {
        x: 275,
        y: 275
    };
    fox.nextmove = 0;
    // Создаем и размещаем клип с кроликом.
    attachMovie("bunny", "bunny", level++);
    bunny._x = 275;
    bunny._y = 125;
    // Определяем направление движения и координаты цели.
    // Запоминаем координаты предыдущего положения,
    bunny.move = {
        x: 1,
        y: 0
    };
    bunny.dest = {
        x: 300,
        y: 125
    };
    bunny.nextmove = 0;
    bunny.last = {
        x: 275,
        y: 125
    };
}
Если Вы заметили ошибку, выделите, пожалуйста, необходимый текст и нажмите CTRL + Enter, чтобы сообщить об этом редактору.